@ECHO OFF
COLOR 0A
ECHO.:::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.::                                             ::
ECHO.::          手机录屏(安卓4.4及以上)V1.0        ::
ECHO.::                                             ::
ECHO.:::::::::::::::::::::::::::::::::::::::::::::::::

:::::::             作者：Findyou                    ::
:::::::      版本:V1.0       时间：2014.12.21       ::
::::::::::::::::::::::::::::::::::::::::::::::::::::::

::**************在此修改目录**************************

SET pcDir=C:\Users\%username%\Pictures
SET phoneDir=/sdcard
::**************在此修改目录**************************
:recordstart
ECHO.[ HELP ] 操作步骤：
ECHO.         1、输入录制时间[回车]
ECHO.         2、按提示开始录制
SET /a SCTIME=10
ECHO.
SET /P SCTIME=[ INFO ] 请输入录制时间(默认10S): 
:MyLoop
SET CONFIRM=Findyou
SET /P CONFIRM=[ INFO ] 确认开始录制？[Enter]
IF NOT "%CONFIRM%"=="Findyou" GOTO MyLoop
ECHO.
ECHO.[ EXEC ] 开始录制视频(Time: %SCTIME%S)
adb shell screenrecord --time-limit %SCTIME% %phoneDir%/screenrecord.mp4

:: 获取得小时,格式为：24小时制，10点前补0
SET c_time_hour=%time:~0,2%
IF /i %c_time_hour% LSS 10 (
SET c_time_hour=0%time:~1,1%
)
ECHO.[ INFO ] 录制结束
ECHO.
ECHO.[ EXEC ] 拷贝录屏至电脑
adb pull %phoneDir%/screenrecord.mp4 "%pcDir%\%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%%time:~6,2%.mp4"

ECHO.[ EXEC ] 打开视频保存目录
start %pcDir%
adb shell rm %phoneDir%/screenrecord.mp4

:BATend
ECHO.
ECHO.[ INFO ] 暂停3秒自动关闭...
ping -n 3 127.0.0.1>nul

 

 

说明:手机助手很多时候很厌烦，经常起自已的adb，导制ADB命令时常出错。此脚本是为了在没有手机助手的情况下进行屏幕录制。

使用方法:双击bat文件即可，默认录制10S，默认保存路径在"我的图片"。

2、[获得当前运行APP包名.bat]

@ECHO OFF
COLOR 0A
ECHO.:::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.::                                             ::
ECHO.::           当前运行的APP包名                 ::
ECHO.::                                             ::
ECHO.:::::::::::::::::::::::::::::::::::::::::::::::::
:::::::             作者：Findyou                   ::
:::::::      版本:V1.0       时间：2014.05.25       ::
::::::::::::::::::::::::::::::::::::::::::::::::::::::
::**************在此修改目录**************************
SET pcDir=%~dp0

FOR /F "tokens=3 delims= " %%a in ('adb shell dumpsys window^|find "mCurrentFocus"') do (
        FOR /F "tokens=1 delims=}" %%i in ("%%a") do (
        ECHO.[ INFO ] 包名/活动名
        ECHO.[ INFO ] %%i
        )
)
ECHO.
PAUSE

 

3、[Activity启动跳转时间监控V1.0.bat]

@ECHO OFF
ECHO.:::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.::                                             ::
ECHO.::     Activity启动跳转时间监控 V1.0           ::
ECHO.::                                             ::
ECHO.:::::::::::::::::::::::::::::::::::::::::::::::::
:::::::             作者：Findyou                    ::
:::::::      版本:V1.0       时间：2014.08.25       ::
::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.[ INFO ] 清空日志
adb logcat -c
ECHO.[ INFO ] 监控开始(Ctrl+C结束)
ECHO.[ INFO ] 保存请拷贝输出内容
adb logcat -s ActivityManager|Findstr /C:": Displayed"

 

4、[查看签名信息(文件拖至此) V1.1.bat]

@ECHO OFF
ECHO.:::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.::                                             ::
ECHO.::             查看APK签名信息                 ::
ECHO.::                                             ::
ECHO.:::::::::::::::::::::::::::::::::::::::::::::::::
:::::::             作者：Findyou                   ::
:::::::      版本:V1.0       时间：2014.08.25       ::
:::::::      版本:V1.1       时间：2014.12.13       ::
::::::::::::::::::::::::::::::::::::::::::::::::::::::
Color 0A
ECHO.
ECHO.[ HELP ] 可查看RSA、APK、keystore签名信息
SET C_PATH=%~dp0
REM 方法：直接将APK或RSA文件到bat文件上
IF NOT "%1"=="" SET apkorFile=%1
IF "%~x1"==".RSA" GOTO RSAFile
IF "%~x1"==".rsa" GOTO RSAFile
IF "%~x1"==".apk" GOTO APKFile
IF "%~x1"==".APK" GOTO APKFile
IF "%~x1"==".keystore" GOTO KEYSTOREFile
IF "%~x1"==".KEYSTORE" GOTO KEYSTOREFile

Color 0D
ECHO.[ INFO ] 你是猴子派来的逗逼吧？
ECHO.[ HELP ] 请将RSA或得APK或者keystore拖至Bat文件上
GOTO BATend

:KEYSTOREFile
DEL "%C_PATH%%~nx1.txt" 2>nul
ECHO.[ INFO ] INPUT：%apkorFile%
ECHO.[ INFO ] OUT: %C_PATH%%~nx1.txt
ECHO.
keytool -list -v -keystore %apkorFile% > "%C_PATH%%~nx1.txt"
type "%C_PATH%%~nx1.txt"
GOTO BATend

:RSAFile
DEL "%C_PATH%%~n1.RSA.txt" 2>nul
ECHO.[ INFO ] INPUT：%apkorFile%
ECHO.[ INFO ] OUT: %C_PATH%%~n1.RSA.txt
ECHO.
keytool -printcert -file %apkorFile% > "%C_PATH%%~n1.RSA.txt"
type "%C_PATH%%~n1.RSA.txt"
GOTO BATend

:APKFile
ECHO.[ INFO ] INPUT：%apkorFile%
ECHO.[ INFO ] OUT: %C_PATH%%~n1.RSA.txt
RD /S /Q %~n1_META-INF 2>nul
::jar tf %apkorFile%|Findstr "RSA"
::解压签名目录
jar -xf %apkorFile% META-INF
::重合名文件夹
REN META-INF %~n1_META-INF
::查看签名文件信息
CD %~n1_META-INF
FOR %%I IN (*.RSA) DO (
    ECHO.[ INFO ] %%I
    ECHO.
    keytool -printcert -file %%I > "%C_PATH%%~n1.RSA.txt"
    type "%C_PATH%%~n1.RSA.txt"
)
CD %~dp1
RD /S /Q %~n1_META-INF 2>nul

:BATend
ECHO.
ECHO.[ EXIT ] 按任意键关闭窗口...
PAUSE>nul

暂进更新到这,Mark 2015-07-23  20：30

朋友反馈目录名错误，已更正   2015-07-23  21:30

 附：